home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / VIC20 / U-Utilities / (v)u1.d64 / diskmem b-rr1 (.txt) < prev    next >
Commodore BASIC  |  2007-02-11  |  2KB  |  61 lines
  1. 100 REM ORIGINAL BY      MR. JIM BUTTERFIELD
  2. 110 REM FROM BEST OF        TRANSACTOR VOL.2      BULLETIN 6
  3. 120 REM MODIFIED FOR   VIC BY ROY R ROBINSON       VANCOUVER B. C.
  4. 130 REM(604)437-8017
  5. 132 REM
  6. 135 REM SEE INSTR.
  7. 140 REM
  8. 150 PRINT"[147] DISK MEMORY DISPLAY  JIM BUTTERFIELD + RRR [146]"
  9. 160 DATA77,45,87,0,18,16,162,0,189
  10. 170 DATA157,64,06,232,224,16,208,245,76,193,254
  11. 180 FORJ=1TO9:READX:C$=C$+CHR$(X):NEXTJ
  12. 190 FORJ=1TO11:READX:D$=D$+CHR$(X):NEXTJ
  13. 200 PRINT" THERE ARE TWO          PROCESSORS:"
  14. 210 PRINT"  1) IEEE PROCESSOR"
  15. 220 PRINT"  2) DISK PROCESSOR"
  16. 230 PRINT"WHICH DO YOU WANT TO   PEEK ([158]1 OR[158] 2)"
  17. 240 GETG$:D=VAL(G$):IFD<>1ANDD<>2THEN240
  18. 250 PRINT"[156]YOUR CHOICE IS#[146]"D
  19. 260 PRINT" ENTER MEMORY ADDRESS   IN HEXADECIMAL:          [196][196][196][196][196][196][196][196][196][196][196]"
  20. 270 OPEN1,8,15:SC=36879
  21. 280 INPUTZ$:IFLEN(Z$)<>4THEN280
  22. 290 PRINTZ$:  PRINT"[145]                      ";
  23. 300 GOTO320
  24. 310 Z$=A$:IFLEN(Z$)<>4THEN280
  25. 320 GOSUB590:PRINT"  $"Z$"";
  26. 330 FORJ=1TO4:Y=ASC(MID$(Z$,J))
  27. 340 IFY<58THENY=Y-48
  28. 350 IFY>64THENY=Y-55
  29. 360 IFY<0ORY>16GOTO280
  30. 370 Y(J)=Y:NEXTJ:K=0:S=0:PRINT"";
  31. 380 ONDGOTO390,410:GOTO230
  32. 390 U=Y(3)*16+Y(4):V=Y(1)*16+Y(2)
  33. 400 GOSUB450:GOTO310
  34. 410 PRINT#1,C$;CHR$(Y(3)*16+Y(4));CHR$(Y(1)*16+Y(2));D$
  35. 420 PRINT#1,"M-W";CHR$(4);CHR$(16);CHR$(1);CHR$(224)
  36. 430 PRINT#1,"M-R";CHR$(4);CHR$(16):GET#1,X$:IFX$=CHR$(224)GOTO430
  37. 440 U=64:V=18:GOSUB450:GOTO310
  38. 450 PRINT#1,"M-R"CHR$(U);CHR$(V)
  39. 460 GET#1,X$:IFX$=""THENX$=CHR$(0)
  40. 470 PRINT" ";:X=ASC(X$)/16
  41. 480 FORJ=1TO2:X%=X:X=(X-X%)*16:IFX%>9THENX%=X%+7
  42. 490 PRINTCHR$(X%+48);:NEXTJ
  43. 500 U=U+1:IFU=256THENU=0:V=V+1:IFV=256THENV=0
  44. 510 S=S+1:IFS=4THENGOSUB580
  45. 520 K=K+1:IFK<8GOTO450
  46. 530 Y(0)=0:Y(4)=Y(4)+8:J=4
  47. 540 IFY(J)>15THENY(J)=Y(J)-16:J=J-1:Y(J)=Y(J)+1:GOTO540
  48. 550 PRINT"[146]"
  49. 560 A$="":PRINT;:FORJ=1TO4:Y=Y(J):IFY>9THENY=Y+7
  50. 570 A$=A$+CHR$(Y+48):NEXTJ:PRINT"[145]":RETURN
  51. 580 PRINTSPC(10);:RETURN
  52. 590 GETA$:IFA$<>" "THENRETURN
  53. 600 PRINT:PRINT"..?"
  54. 610 GETA$:IFA$="A"THEN650
  55. 620 IFA$="X"THEN:CLOSE1:END
  56. 625 IFA$="R"THENCLOSE1:GOTO200
  57. 630 IFA$<>" "THENGOTO610
  58. 640 RETURN
  59. 650 PRINT: PRINT" ENTER MEMORY ADDRESS    IN HEXADECIMAL:          [196][196][196][196][196][196][196][196][196][196][196]"
  60. 660 INPUTA$:GOTO310
  61.